┌──────────────────────────────────────┐
│Option Explicit                                                             │
│'***************************************************************************│
│'  クラス：ファイル出力                                                     │
│'***************************************************************************│
│Private m出力シート As Worksheet                                            │
│'===========================================================================│
│'  コンストラクタ                                                           │
│'===========================================================================│
│Private Sub Class_Initialize()                                              │
│End Sub                                                                     │
│'===========================================================================│
│'  メソッド：準コンストラクタ                                               │
│'===========================================================================│
│Public Sub 準コンストラクタ(ByVal 出力シート名 As String)                   │
│    Set m出力シート = ThisWorkbook.Worksheets(出力シート名)                 │
│End Sub                                                                     │
│'===========================================================================│
│'  デストラクタ                                                             │
│'===========================================================================│
│Private Sub Class_Terminate()                                               │
│End Sub                                                                     │
│'===========================================================================│
│'  実行：ファイル出力                                                       │
│'===========================================================================│
│Private Sub 実行()                                                          │
│    Dim 出力先 As Variant                                                   │
│    ' 出力先選択                                                            │
│    出力先 = 出力先選択()                                                   │
│    If 出力先 = "" Then                                                     │
│        Exit Sub                                                            │
│    End If                                                                  │
│    ' 複写                                                                  │
│    m出力シート.Copy                                                        │
│    ' 保存                                                                  │
│    Application.DisplayAlerts = False   ' 確認ダイアログ抑止(強制上書)      │
│    ActiveWorkbook.SaveAs Filename:=出力先, _                               │
│                          FileFormat:=XlFileFormat.xlOpenXMLWorkbook        │
│    Application.DisplayAlerts = True    ' 確認ダイアログ抑止解除            │
│    ActiveWorkbook.Close SaveChanges:=False                                 │
│End Sub                                                                     │
│'===========================================================================│
│'  内部メソッド：出力先選択                                                 │
│'===========================================================================│
│Private Function 出力先選択() As String                                     │
│    Dim メッセージ As String                                                │
│    Dim 出力先 As Variant                                                   │
│    Dim ファイル名 As String                                                │
│    ファイル名 = ファイル名編集(m出力シート.Name) & ".xlsx" ' 初期表示      │
│    Do                                                                      │
│        出力先 = Application.GetSaveAsFilename( _                           │
│            InitialFileName:=ファイル名, _                                  │
│            FileFilter:="Excelファイル(*.xlsx),*.xlsx" _                    │
│        )                                                                   │
│        ' キャンセル                                                        │
│        If 出力先 = False Then                                              │
│            MsgBox "キャンセルされました。", vbInformation, "処理の中止"    │
│            出力先選択 = ""                                                 │
│            Exit Function                                                   │
│        End If                                                              │
│        ' 新規追加                                                          │
│        If Dir(出力先) = "" Then                                            │
│            Exit Do                                                         │
│        End If                                                              │
│        ' 上書の確認                                                        │
│        ファイル名 = Dir(出力先)                                            │
│        メッセージ = ファイル名 & " は既に存在します。" & vbCrLf _          │
│                   & "上書きしますか？"                                     │
│        If MsgBox(メッセージ, vbYesNo + vbExclamation, "処理の確認") _      │
│                                                                = vbYes Then│
│            Exit Do                                                         │
│        End If                                                              │
│    Loop                                                                    │
│    出力先選択 = 出力先                                                     │
│End Function                                                                │
│'===========================================================================│
│'  内部メソッド：ファイル名編集  ファイル使用不可文字を置換                 │
│'===========================================================================│
│Private Function ファイル名編集(ByVal ファイル名 As String) As String       │
│    ファイル名 = Replace(ファイル名, "<", "(")                              │
│    ファイル名 = Replace(ファイル名, ">", ")")                              │
│    ファイル名編集 = ファイル名                                             │
│End Function                                                                │
│'***************************************************************************│
└──────────────────────────────────────┘
シートをファイル出力するクラスも作ってみた。

以下のようにして使う。
┌──────────────────────────────────────┐
│Dim objファイル出力 As New Classファイル出力                                │
│Call objファイル出力.準コンストラクタ("出力")  ' 任意のシート名を指定       │
│Call objファイル出力.実行()                                                 │
└──────────────────────────────────────┘

┌──────────────────────────────────────┐
│Option Explicit                                                             │
│'***************************************************************************│
│'  クラス：シート複写                                                       │
│'***************************************************************************│
│Private m入力シート As Worksheet                                            │
│'===========================================================================│
│'  コンストラクタ                                                           │
│'===========================================================================│
│Private Sub Class_Initialize()                                              │
│    Set m入力シート = ThisWorkbook.Worksheets("入力")  ' 任意のシート名を   │
│End Sub                                                                     │
│'===========================================================================│
│'  デストラクタ                                                             │
│'===========================================================================│
│Private Sub Class_Terminate()                                               │
│End Sub                                                                     │
│'===========================================================================│
│'  実行                                                                     │
│'===========================================================================│
│Public Sub 実行(ByVal シート名 As String)                                   │
│    Dim シート As Worksheet                                                 │
│    Application.ScreenUpdating = False  ' 作業過程非表示                    │
│    ' シート追加                                                            │
│    For Each シート In Worksheets                                           │
│        If シート.Name = シート名 Then                                      │
│            MsgBox "同一シート名が既に存在します。", vbCritical, "処理中止" │
│            Exit Sub                                                        │
│        End If                                                              │
│    Next シート                                                             │
│    Worksheets.Add(after:=Worksheets(Worksheets.Count)).Name = シート名     │
│    ' シート複写                                                            │
│    Call マクロ抜きシート複写(m入力シート, _                                │
│                              ThisWorkbook.Worksheets(シート名))            │
│    '                                                                       │
│    Application.GoTo m入力シート.Cells(1, 1)                                │
│    Application.ScreenUpdating = True   ' 作業過程非表示の解除              │
│End Sub                                                                     │
│'===========================================================================│
│'  マクロ抜きシート複写                                                     │
│'===========================================================================│
│Private Sub マクロ抜きシート複写(ByVal 入力シート As Worksheet, _           │
│                                 ByVal 出力シート As Worksheet)             │
│    Dim 表示倍率 As Long, 改頁 As Variant                                   │
│    ' コピー                                                                │
│    入力シート.Cells.Copy  ' コピー                                         │
│    With 出力シート.Cells(1, 1)                                             │
│        .PasteSpecial Paste:=xlValues   ' 値貼り付け                        │
│        .PasteSpecial Paste:=xlFormats  ' 書式貼り付け                      │
│        .Select                                                             │
│    End With                                                                │
│    ' 印刷設定の複写                                                        │
│    Call 印刷設定の複写(入力シート.PageSetup, _                             │
│                        出力シート.PageSetup)                               │
│    ' 改頁位置の複写                                                        │
│    For Each 改頁 In 入力シート.HPageBreaks                                 │
│        出力シート.HPageBreaks.Add 改頁.Location.Rows                       │
│    Next 改頁                                                               │
│    ' 表示倍率の複写                                                        │
│    入力シート.Select                                                       │
│    表示倍率 = ActiveWindow.Zoom                                            │
│    出力シート.Select                                                       │
│    ActiveWindow.Zoom = 表示倍率                                            │
│    ' クリップボードのクリア                                                │
│    Application.CutCopyMode = False                                         │
│    ' 上記のみではクリアできないものについては、                            │
│    ' 全セル選択から一セル選択に切り替える                                  │
│    ' →「図が大きすぎます。」エラー対策                                    │
│    入力シート.Cells(1, 1).Copy                                             │
│End Sub                                                                     │
│'===========================================================================│
│'  印刷設定の複写                                                           │
│'===========================================================================│
│Private Sub 印刷設定の複写(ByVal 入力 As Object, _                          │
│                           ByVal 出力 As Object)                            │
│    With 出力                                                               │
│        ' ヘッダ・フッタの複写                                              │
│        .LeftHeader = 入力.LeftHeader                                       │
│        .CenterHeader = 入力.CenterHeader                                   │
│        .RightHeader = 入力.RightHeader                                     │
│        .LeftFooter = 入力.LeftFooter                                       │
│        .CenterFooter = 入力.CenterFooter                                   │
│        .RightFooter = 入力.RightFooter                                     │
│        ' 印刷タイトルの複写                                                │
│        .PrintTitleRows = 入力.PrintTitleRows                               │
│        ' 印刷範囲の複写                                                    │
│        .PrintArea = 入力.PrintArea                                         │
│        .PaperSize = 入力.PaperSize                                         │
│        .Orientation = 入力.Orientation                                     │
│        .Zoom = 入力.Zoom                                                   │
│        .FitToPagesTall = 入力.FitToPagesTall                               │
│        .FitToPagesWide = 入力.FitToPagesWide                               │
│    End With                                                                │
│End Sub                                                                     │
│'***************************************************************************│
└──────────────────────────────────────┘
シートをマクロ抜きで複写するクラスを作ってみた。

以下のようにして使う。
┌──────────────────────────────────────┐
│Dim objシート複写 As New Classシート複写                                    │
│Call objシート複写.実行("出力")  ' 任意のシート名を指定                     │
└──────────────────────────────────────┘

ただ、印刷範囲あたりの処理はナイーヴ(Excelのバグ？)なので、
ボタン等があればおかしくなる可能性もあるので注意して使用のこと。

┌──────────────────────────────────────┐
│Dim i As Integer                                                            │
│Dim 図形名 As String, 上 As Double, 左 As Double, 縦 As Double, 横 As Double│
│With 入力シート                                                             │
│    For i = 1 To .Shapes.Count                                              │
│        With .Shapes(i)                                                     │
│            図形名 = .Name                                                  │
│            上 = .Top                                                       │
│            左 = .Left                                                      │
│            縦 = .Height                                                    │
│            横 = .Width                                                     │
│            .Copy                                                           │
│        End With                                                            │
│        With 出力シート                                                     │
│            .Select                                                         │
│            .Paste                                                          │
│            If VarType(Selection) = vbObject Then                           │
│                Selection.Name = 図形名  ' 日本語既定名は英語になるので注意 │
│            End If                                                          │
│            With .Shapes(図形名)                                            │
│                .Top = 上                                                   │
│                .Left = 左                                                  │
│                .Height = 縦                                                │
│                .Width = 横                                                 │
│            End With                                                        │
│            .Cells(1, 1).Select                                             │
│        End With                                                            │
│    Next i                                                                  │
│End With                                                                    │
└──────────────────────────────────────┘
コピーして名称を合わせて位置も合わせた。

AcitiveXコントロールの場合は、ペーストを選択(Selection)されない代わり
図形名は同じになるので、それ以外の場合のみ図形名を合わせる処理を行い
その後、図形名が同じという前提で、位置を合わせた。

なお、日本語既定名は実体は英語名なので、英語名としてコピーされてしまう。

そのオートシェイプを選択した状態で、画面左上の窓(名前ボックス)には
確かに「テキスト ボックス 1」と表示されているのだが、
ExcelVBAの名前取得では「Text Box 1」となってしまう件。

典型的な例が以下。
┌──────────────────────────────────────┐
│MsgBox シート.Shapes("テキスト ボックス 1").Name           '→「Text Box 1」│
└──────────────────────────────────────┘
確かに「テキスト ボックス 1」でオートシェイプを指定できているのにも関わらず
名前属性(.Name)を取得してみたら「Text Box 1」なのだ。

これは既定の場合にのみ起きる怪現象で、名前を変更すれば両者の乖離は解消する。

どうやら、既定値を気を利かして和訳表示したものの、
ExcelVBAと辻褄が合わなくなったことによるようだ。

この場合、名前属性(.Name)で「テキスト ボックス 1」の方を
取得する方法はないようなので、
気になるなら名前属性(.Name)を任意のものに変更するしかないようだ。

任意のものといっても思いつかないという場合には、自身を代入しなおせばよい。
┌──────────────────────────────────────┐
│With シート.Shapes("テキスト ボックス 1")                                   │
│    .Name = .Name                                                           │
│End With                                                                    │
└──────────────────────────────────────┘
すると、「Text Box 1」に名前ボックスの表示も統一される。

以後「テキスト ボックス 1」は使えないが………と思ったら、
以下は引き続き使えてしまった。
┌──────────────────────────────────────┐
│MsgBox シート.Shapes("テキスト ボックス 1").Name           '→「Text Box 1」│
└──────────────────────────────────────┘

ちなみに名前属性(.Name)を関係ないものに変更して実験してみた。
┌──────────────────────────────────────┐
│MsgBox シート.Shapes("テキスト ボックス 1").Name             '→変更した名前│
├──────────────────────────────────────┤
│MsgBox シート.Shapes("Text Box 1").Name                      '→エラー      │
└──────────────────────────────────────┘
つまり、英語側の既定値はまさに既定値で最初だけ有効(変名したそちらへ)なのだが
日本語側の既定値は半永久的に使える存在なのかもしれない。

ややこし過ぎる。

┌──────────────────────────────────────┐
│Dim i As Integer                                                            │
│With シート                                                                 │
│    For i = .Shapes.Count To 1 Step -1                                      │
│        .Shapes(i).Delete                                                   │
│    Next i                                                                  │
│End With                                                                    │
└──────────────────────────────────────┘

┌──────────────────────────────────────┐
│入力シート.Shapes("テキスト ボックス").Copy                                 │
│With 出力シート                                                             │
│    .Cells(3, 3).Select                                                     │
│    .Paste                                                                  │
│End With                                                                    │
└──────────────────────────────────────┘
テキストボックスに数式(参照先)が設定されていたら
そのまま相対的にコピー先のセル(参照先)を指すことになる。

      ┌──┬──┬──┐
      │ 月 │ 値 │累計│
      ├──┼──┼──┤
 1件目│   4│   1│   1│
      ├──┼──┼──┤
 2件目│   5│  10│  11│
      ├──┼──┼──┤
 3件目│   6│ 100│ 111│
      └──┴──┴──┘
こういったデータの場合、その月までの累計をとるとして、その数式は
PowerBI(DAX関数)ではどのように設定するか？(ExcelならSUMIF()なのだが)

方法としては二通りある。
┌──────────────────────────────────────┐
│累計 = SUMX(FILTER('クエリ名', [月] <= EARLIER([月])), [値])                │
├──────────────────────────────────────┤
│累計 = CALCULATE(SUM([値]), FILTER('クエリ名', [月] <= EARLIER([月])))      │
└──────────────────────────────────────┘

EARLIER()はその行のみを指す関数である。
ちなみにEARLIER()なしで「FILTER('クエリ名', [月] <= [月])」とすると
自身(月)同士をおのおので比較するのですべて真になってしまう。

         A列   B列   C列
      ┌──┬──┬──┐
 1行目│ 月 │ 値 │累計│
      ├──┼──┼──┤
 2行目│   4│   1│   1│=SUMIF(A:A,"<="&A2,B:B)
      ├──┼──┼──┤
 3行目│   5│  10│  11│=SUMIF(A:A,"<="&A3,B:B)
      ├──┼──┼──┤
 4行目│   6│ 100│ 111│=SUMIF(A:A,"<="&A4,B:B)
      └──┴──┴──┘
上記のようにC列の累計をとりたい場合、
C列の数式は上記のように設定すればよい。

では、自前で上書保存か否かの判断を行うには？
┌──────────────────────────────────────┐
│If Dir(保存先) = "" Then                                                    │
│    ' 既存なし(上書保存ではなく新規保存)                                    │
│Else                                                                        │
│    ' 既存あり(上書保存)                                                    │
│End If                                                                      │
└──────────────────────────────────────┘
Dir()で保存先があれば戻り値が帰ってくるので、それがあるか否かで判断できる

例えば、ファイル選択ダイアログと組み合わせた場合には
以下のような処理となる。
(上書を拒否したら再度選択画面に戻る仕組みとなっている)
┌──────────────────────────────────────┐
│Function 保存先選択() As String                                             │
│    Dim メッセージ As String                                                │
│    Dim 保存先 As Variant                                                   │
│    Dim ファイル名 As String                                                │
│    ファイル名 = "初期表示ファイル名.xlsx"                                  │
│    Do                                                                      │
│        保存先 = Application.GetSaveAsFilename( _                           │
│            InitialFileName:=ファイル名, _                                  │
│            FileFilter:="Excelファイル(*.xlsx),*.xlsx" _                    │
│        )                                                                   │
│        ' キャンセル                                                        │
│        If 保存先 = False Then                                              │
│            MsgBox "キャンセルされました。", vbInformation, "処理の中止"    │
│            保存先選択 = ""                                                 │
│            Exit Function                                                   │
│        End If                                                              │
│        ' 新規追加                                                          │
│        If Dir(保存先) = "" Then                                            │
│            Exit Do                                                         │
│        End If                                                              │
│        ' 上書の確認                                                        │
│        ファイル名 = Dir(保存先)                                            │
│        メッセージ = ファイル名 & " は既に存在します。" & vbCrLf _          │
│                   & "上書きしますか？"                                     │
│        If MsgBox(メッセージ, vbYesNo + vbExclamation, "処理の確認") _      │
│                                                                = vbYes Then│
│            Exit Do                                                         │
│        End If                                                              │
│    Loop                                                                    │
│    保存先選択 = 保存先                                                     │
│End Function                                                                │
└──────────────────────────────────────┘

基本的に、以下のようにブックを保存した場合、保存先のパスに同一ファイル名があると
保存するか否かのダイアログが開いてしまう。
(そこで「いいえ」とかにするとエラーになってしまう)
┌──────────────────────────────────────┐
│ブック.SaveAs Filename:=保存先, _                                           │
│              FileFormat:=XlFileFormat.xlOpenXMLWorkbook                    │
└──────────────────────────────────────┘

これを避けるためには、その前後で、
警告メッセージ(DisplayAlerts)を一時的に切ればよい。
┌──────────────────────────────────────┐
│Application.DisplayAlerts = False                                           │
│ブック.SaveAs Filename:=保存先, _                                           │
│              FileFormat:=XlFileFormat.xlOpenXMLWorkbook                    │
│Application.DisplayAlerts = True                                            │
└──────────────────────────────────────┘
シート削除(こちらも確認ダイアログが開く)時と同じ要領だ。